共有しているExcelの値が変わっているのに、誰がいつ直したのか分からない。そんなときの記事です。
結論は2つあります。ファイルが OneDrive や SharePoint にあるなら、まず標準の履歴機能で足りるかを確かめます。社内のファイルサーバーに置いているなら、VBA の Worksheet_Change で、変更を1件ずつ別のシートに書き出します。
私も、決まった様式の文書で「誰がどこを変えたか」を追いたくて、VBA で記録の仕組みを作ったことがあります。役には立ちましたが、変更箇所を並べただけだったので、あとから追うのが大変でした。この記事では、どの行のどの項目かを一緒に残して、あとで絞り込める形にします。
この記事で分かること
- 作る前に確かめること(クラウドの履歴機能で足りるか)
- セルが変わるたびに、日時・ユーザー・変更前・変更後を記録するコード
- 変更前の値を残すための「控え」シートの使い方
- 文書番号で絞り込んで、1件の経緯を追う方法
- この方法では記録できないこと
完成形はこうなります。

完成形。台帳を5回書き換えたあとの「変更履歴」シート
どんな場面で使うか
- 共有フォルダの台帳やマスターを、複数の人が1人ずつ開いて更新している
- 値が変わった経緯を、あとから聞かれることがある
- 「誰かが直したらしい」で話が止まり、確かめる手段が無い
対象は Windows 版の Excel です。
作る前に:標準の機能で足りるかを確かめる
ファイルの置き場所によって、使える手段が変わります。
| 置き場所 | 手段 | 分かること |
|---|---|---|
| OneDrive・SharePoint | バージョン履歴 | 保存された版ごとの日時と更新者。前の版を開いて見比べられる |
| OneDrive・SharePoint | 「校閲」タブの「変更内容を表示」 | セルごとの、変えた人・日時・変更前と変更後の値 |
| 社内のファイルサーバー | この記事のマクロ | 自分で決めた項目 |
クラウドに置いているなら履歴は標準の機能で取れるので、そもそも作る必要が無いことがあります。作る前に、その機能が要求に合うかを先に見たほうがよい。これが、作ってみた私の考えです。
上の2つの機能が使えるかどうかと、さかのぼれる期間は、Excel の種類や管理者の設定で変わります。お使いの環境で確かめてください。
基本説明
サンプルファイル(記事末尾)を使います。シートは次の3つです。
| シート | 役割 |
|---|---|
| 台帳 | 人が書き換える表。変更を記録する対象 |
| 変更履歴 | マクロが1件ずつ書き足す |
| 控え | 台帳の写し。変更前の値を知るために使う |
「台帳」シートは文書の一覧で、A1:G9 に8件が入っています。

元データ。「台帳」シート(文書番号・文書名・版・担当・状態・期限・備考)
Worksheet_Change で分かるのは「変更後」だけ
Worksheet_Change は、シートのセルが書き換えられた直後に動くイベントです。動いた時点で、セルの値はもう新しい値に変わっています。
変更前の値を残すには、書き換えられる前の値をどこかに持っておく必要があります。この記事では、台帳と同じ内容の「控え」シートを持ち、同じ番地のセルを見て変更前の値を取り出します。記録したあとで、控えのセルも新しい値に合わせます。
履歴に残す項目
私が以前作ったものは、変更箇所を並べただけで、あとから追うのが大変でした。この記事では「文書番号」と「項目」の列を足して、フィルターで絞り込めるようにします。
| 列 | 中身 | 例 |
|---|---|---|
| A 日時 | 変更した日時 | — |
| B ユーザー | Windows にサインインしている名前 | — |
| C セル | 変わったセルの番地 | E3 |
| D 文書番号 | 変わった行のA列の値 | D-002 |
| E 項目 | 変わった列の見出し | 状態 |
| F 変更前 | 控えシートにあった値 | 作成中 |
| G 変更後 | 書き換えたあとの値 | レビュー中 |
手順
ステップ1 記録用のシートを2枚用意する
サンプルファイルには用意してあります。自分のブックで作るときは、次のようにします。
- シートを2枚足し、名前を「変更履歴」「控え」にします
- 「変更履歴」シートの1行目に、上の表の見出しを7つ入れます

「変更履歴」シートの見出しと、3つのシート見出し(台帳・変更履歴・控え)
ステップ2 標準モジュールにコードを貼る
記録する処理の本体です。
- 「Alt」キーを押しながら「F11」キーを押して、VBEを開きます
- 「挿入」→「標準モジュール」を選びます
- 下のコードを貼り付けます
Option Explicit
' シート名と列の位置(ブックに合わせて変える)
Private Const DATA_SHEET As String = "台帳"
Private Const LOG_SHEET As String = "変更履歴"
Private Const MIRROR_SHEET As String = "控え"
Private Const HEADER_ROW As Long = 1 ' 見出しの行
Private Const KEY_COL As Long = 1 ' A列: 行を見分ける番号(文書番号)
Private Const MAX_CELLS As Long = 200 ' これを超える変更は1行にまとめる
' 台帳シートの Worksheet_Change から呼ぶ: 変わったセルを変更履歴に書く
Public Sub RecordChange(ByVal Target As Range)
Dim wsData As Worksheet
Dim wsLog As Worksheet
Dim wsMirror As Worksheet
Dim c As Range
Dim oldText As String
Dim newText As String
On Error GoTo CleanUp
Application.EnableEvents = False ' 記録中の書き込みで、もう一度呼ばれないようにする
Set wsData = Target.Worksheet
Set wsLog = ThisWorkbook.Worksheets(LOG_SHEET)
Set wsMirror = ThisWorkbook.Worksheets(MIRROR_SHEET)
If Target.CountLarge > MAX_CELLS Then
' 行・列の挿入や削除、大きな貼り付けは、中身を追わずに1行だけ残す
WriteLog wsLog, Target.Address(False, False), "", "(まとめて変更)", "", ""
CopyToMirror wsData, wsMirror
Else
For Each c In Target.Cells
oldText = ToText(wsMirror.Range(c.Address).Value)
newText = ToText(c.Value)
If oldText <> newText Then
WriteLog wsLog, c.Address(False, False), _
ToText(wsData.Cells(c.Row, KEY_COL).Value), _
ToText(wsData.Cells(HEADER_ROW, c.Column).Value), _
oldText, newText
' 控えを新しい値に合わせる
c.Copy Destination:=wsMirror.Range(c.Address)
End If
Next c
End If
CleanUp:
Application.EnableEvents = True
If Err.Number <> 0 Then
MsgBox "変更履歴を書けませんでした: " & Err.Description, vbExclamation
End If
End Sub
' マクロの一覧から実行する: 台帳の今の内容で、控えを作り直す
Public Sub 控えを取り直す()
On Error GoTo CleanUp
Application.EnableEvents = False
CopyToMirror ThisWorkbook.Worksheets(DATA_SHEET), _
ThisWorkbook.Worksheets(MIRROR_SHEET)
CleanUp:
Application.EnableEvents = True
If Err.Number <> 0 Then
MsgBox "控えを取り直せませんでした: " & Err.Description, vbExclamation
Else
MsgBox "控えを取り直しました。", vbInformation
End If
End Sub
' 変更履歴の最後の行の下に、1件書く
Private Sub WriteLog(ByVal wsLog As Worksheet, ByVal cellAddress As String, _
ByVal keyText As String, ByVal itemText As String, _
ByVal oldText As String, ByVal newText As String)
Dim logRow As Long
' 絞り込んだままだと、隠れている行に上書きしてしまうので解除する
If wsLog.FilterMode Then wsLog.ShowAllData
logRow = wsLog.Cells(wsLog.Rows.Count, 1).End(xlUp).Row + 1
' 「007」のような値が数値に変わらないように、文字列として書く
wsLog.Range(wsLog.Cells(logRow, 2), wsLog.Cells(logRow, 7)).NumberFormat = "@"
wsLog.Cells(logRow, 1).NumberFormat = "yyyy/mm/dd hh:mm:ss"
wsLog.Cells(logRow, 1).Value = Now
wsLog.Cells(logRow, 2).Value = Environ("USERNAME")
wsLog.Cells(logRow, 3).Value = cellAddress
wsLog.Cells(logRow, 4).Value = keyText
wsLog.Cells(logRow, 5).Value = itemText
wsLog.Cells(logRow, 6).Value = oldText
wsLog.Cells(logRow, 7).Value = newText
End Sub
' 台帳の使っている範囲を、控えの同じ番地に写す
Private Sub CopyToMirror(ByVal wsData As Worksheet, ByVal wsMirror As Worksheet)
wsMirror.Cells.Clear
wsData.UsedRange.Copy Destination:=wsMirror.Range(wsData.UsedRange.Address)
End Sub
' セルの値を、履歴に書く文字に直す
Private Function ToText(ByVal v As Variant) As String
If IsError(v) Then
ToText = "(エラー値)"
ElseIf VarType(v) = vbDate Then
If CDbl(v) = Int(CDbl(v)) Then
ToText = Format(v, "yyyy/mm/dd")
Else
ToText = Format(v, "yyyy/mm/dd hh:nn:ss")
End If
Else
ToText = CStr(v)
End If
End Function
モジュールの先頭にすでに Option Explicit があるときは、その行は重ねて貼りません。
ユーザー名に Application.UserName を使っていないのは、Excel のオプションで誰でも書き換えられる名前だからです。
ステップ3 「台帳」シートのモジュールにコードを貼る
イベントのコードは、記録したいシートのモジュールに置きます。標準モジュールに貼っても動きません。
- VBEの左側(プロジェクト エクスプローラー)で、「Sheet1 (台帳)」のように台帳の名前が付いた行をダブルクリックします
- 開いた画面に、下のコードを貼り付けます
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
RecordChange Target
End Sub

VBEで「台帳」シートのモジュールを開き、Worksheet_Change を貼った画面
ステップ4 控えを取り直して、マクロ有効ブックで保存する
- Excel の画面に戻り、「Alt」キーを押しながら「F8」キーを押します
- 「控えを取り直す」を選んで「実行」を押します
- 「控えを取り直しました。」と表示されたら「OK」を押します
- ブックを「Excel マクロ有効ブック(*.xlsm)」で保存します
控えは、台帳と中身がそろっていることが前提です。自分のブックでは、使い始める前に必ず1回実行します。
ステップ5 セルを書き換えて確かめる
- 「台帳」シートの E3(D-002 の状態)を「レビュー中」に書き換えます
- 「変更履歴」シートを開きます

1回書き換えた直後の「変更履歴」シート(2行目に1件)
2行目に、セル「E3」・文書番号「D-002」・項目「状態」・変更前「作成中」・変更後「レビュー中」が入ります。
ステップ6 文書番号で絞って、1件の経緯を追う
履歴は時間の順に並ぶので、件数が増えると1件の経緯を目で追えなくなります。文書番号で絞ります。
- 「変更履歴」シートの見出しのセルを選び、「データ」→「フィルター」を押します
- D1(文書番号)の ▼ を押し、「D-002」だけにチェックを残して「OK」を押します

「変更履歴」を文書番号 D-002 で絞り込んだ画面(3件)
下の「動作確認」の5回の書き換えのあとなら、D-002 の3件だけが残ります。状態が「作成中」→「レビュー中」→「承認済み」と進み、途中で期限が延びたことが読み取れます。
絞り込んだまま台帳を書き換えると、マクロが記録の前に絞り込みを解除します。絞ったままだと最後の行を正しく探せず、隠れている記録に上書きしてしまうためです。
動作確認
サンプルファイル(記事末尾)にステップ2〜4を行ったあと、「台帳」シートで次の5つを順に書き換えます。
| 順 | セル | 書き換える内容 |
|---|---|---|
| 1 | E3 | 「レビュー中」にする |
| 2 | D5 | 「高橋」にする |
| 3 | F3 | 「2026/12/15」にする |
| 4 | G6 | 「様式を改訂」と入れる |
| 5 | E3 | 「承認済み」にする |
「変更履歴」シートの2〜6行目が次のとおりになれば成功です。A列には書き換えた日時、B列には Windows のサインイン名が入ります。
| 行 | C セル | D 文書番号 | E 項目 | F 変更前 | G 変更後 |
|---|---|---|---|---|---|
| 2 | E3 | D-002 | 状態 | 作成中 | レビュー中 |
| 3 | D5 | D-004 | 担当 | 佐藤 | 高橋 |
| 4 | F3 | D-002 | 期限 | 2026/11/30 | 2026/12/15 |
| 5 | G6 | D-005 | 備考 | (空) | 様式を改訂 |
| 6 | E3 | D-002 | 状態 | レビュー中 | 承認済み |
表の「(空)」は、変更前のセルが空欄だったという意味です。履歴のセルも空欄のまま残ります。
同じ値を入れ直したとき(たとえば D5 にもう一度「高橋」)は、行が増えないことも確かめます。
この方法では記録できないこと
作る前に知っておくほうがよい限界です。要求に合わないなら、置き場所や手段のほうを見直します。
- マクロを有効にせずに開いた人の変更は、記録されません。 その間に控えもずれます
- 数式の再計算で値が変わっただけでは、記録されません。
Worksheet_Changeは、セルが書き換えられたときに動くイベントです - 200セルを超える変更は、1行にまとめます。 行や列の挿入・削除もこちらに入り、項目に「(まとめて変更)」とだけ残ります
- 履歴は同じブックの中にあるので、書き換えも削除もできます。 経緯を追うための記録で、不正が無いことの証明にはなりません
- 台帳は並べ替えないでください。 並べ替えでセルの位置が入れ替わると、実際には変わっていない文書の値が「変更」として記録されることがあります。見るときはフィルターで絞ります
- 台帳シートでは「元に戻す」(Ctrl+Z)が使えなくなります。 マクロがセルに書き込むと、Excel の「元に戻す」の履歴が消えるためです
よくあるエラー
書き換えても、変更履歴に行が増えない
原因: 次のどれかのことが多いです。
Worksheet_Changeを標準モジュールや別のシートのモジュールに貼っている- マクロが無効のまま開いている
- マクロを途中で止めたあと、イベントが止まったままになっている
直し方: 上から順に確かめます。3つ目は、VBEのイミディエイトウィンドウに Application.EnableEvents = True と入れて「Enter」キーを押します。
「変更履歴を書けませんでした: インデックスが有効範囲にありません。」と表示される
原因: 「変更履歴」「控え」のどちらかのシートが無いか、名前がコードの先頭の定数と違います。
直し方: シート名を戻すか、LOG_SHEET・MIRROR_SHEET の値を今のシート名に合わせます。
変更前の値が、実際と違う
原因: 控えが台帳とずれています。マクロが無効のまま編集された、控えを直接書き換えた、などで起きます。
直し方: 「控えを取り直す」を実行します。ずれていた間の変更は、さかのぼって記録できません。
保存して開き直したら、マクロが消えている
原因: 「Excel ブック(*.xlsx)」で保存しています。この形式にはマクロを保存できません。
直し方: 「Excel マクロ有効ブック(*.xlsm)」で保存し直します。保存の手順はマクロの始め方の記事にあります。
まとめ
- OneDrive・SharePoint に置いているなら、先に標準の履歴機能が要求に合うかを確かめる
- ファイルサーバーのブックは、
Worksheet_Changeで変更を別シートに書き出す - 変更前の値は、台帳の写し(控え)から取り出す
- 「文書番号」と「項目」を一緒に残すと、フィルターで1件の経緯を追える
- マクロ無効で開いた変更・再計算による変化は残らない。証明ではなく、経緯を追うための記録として使う
関連記事
- 【Excel】他の人が編集できないようにする3つの設定 — 読み取り専用・書き込みパスワード・シートの保護
- 【Excel VBA】 マクロの始め方
- 【VBA】実行時エラー番号別の原因と対処一覧(1004・9・13・91…)
- 【業務改善】課題管理表が続くかは「周辺作業」で決まる — Excelの一覧と詳細シートを関数とマクロでつなぐ
サンプルファイル
記事中で使用しているサンプルデータはこちらからダウンロードできます。
